[Zope-Checkins] CVS: Zope - configure.bat:1.1.2.1

[Chris McDonough]

Update of /cvs-repository/Zope
In directory cvs.zope.org:/tmp/cvs-serv17700

Added Files:
      Tag: chrism-install-branch
	configure.bat 
Log Message:
First stab at allowing Windows users  with VC++ to build Zope from source.

The dance is (from an NT command shell): configure.bat; nmake build; nmake install.




=== Added File Zope/configure.bat ===
@echo off
rem Zope source configure script for win32
rem Assumes youre running on WinNT/2000/XP
rem To make and compile Zope you will need MS VC++
rem TO specify a Python interpreter to use, issue the command
rem "set PYTHON=\path\to\your\python"
rem If this script doesnt work for you for some reason, instead just run
rem "YOUR_PYTHON_EXECUTABLE inst\configure.py --prefix=ZOPE_TARGET_DIR"

rem $Id: configure.bat,v 1.1.2.1 2002/10/05 22:47:03 chrism Exp $
rem $Revision: 1.1.2.1 $

set PYTHON_TARGET_VER=2.1
set DEFAULT_PREFIX=C:\Zope
echo.

:getpythonfromenv
 if "%PYTHON%"=="" goto findpython
 if not exist "%PYTHON%" goto nosuchexecutable
 set FOUND_PYTHON=%PYTHON%

:configure
 "%FOUND_PYTHON%" inst\configure.py %1 %2 %3 %4
 if not errorlevel 1 goto :EOF

:usage
 echo configure [--prefix=target_dir] [--ignore-largefile] [--ignore-zlib] 
 echo.
 echo Creates a Makefile suitable for building and installing Zope with Visual C++
 echo.
 echo   Options:
 echo     --prefix            the directory in which you wish to install Zope
 echo                         (e.g. --prefix=c:\Program Files\Zope)
 echo                         defaults to c:\Zope
 echo     --ignore-largefile  ignore large file support warnings
 echo     --ignore-zlib       ignore warnings about zlib
 echo.
 echo   Special:
 echo     To specify a Python interpreter to use, issue the command
 echo     "set PYTHON=\path\to\your\python\executable" before running
 echo     this script.
 echo.
 goto :EOF

:findpython
 echo Finding a Python interpreter
 regedit /E "%Temp%\python-for-zope.reg" "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Python.exe"
 if not exist "%Temp%\python-for-zope.reg" goto nopython
 for /F "tokens=1* delims==" %%A IN ('TYPE %Temp%\python-for-zope.reg ^| FIND "Python.exe"') DO set FOUND_PYTHON=%%B
 set FOUND_PYTHON=%FOUND_PYTHON:"=%
 echo A Python interpreter was found at %FOUND_PYTHON%
 echo %FOUND_PYTHON% | FIND "%PYTHON_TARGET_VER%" >NUL
 if errorlevel 1 goto badpython
 del %Temp%\python-for-zope.reg
 goto configure

:badpython
 echo.
 echo !! ERROR !!
 echo The version of Python you've installed on your computer at
 echo %FOUND_PYTHON% is not capable of running Zope.  Use Python
 echo version %TARGET_PYTHON_VER% instead.  Download and install it
 echo from http://www.python.org.
 echo.
 goto usage

:nosuchexecutable
 echo.
 echo !! ERROR !!
 echo The Python interpreter you've specified ("%PYTHON%") via the PYTHON
 echo environment variable does not appear to exist.
 echo.
 goto usage

:nopython
 echo.
 echo !! ERROR !!
 echo Python is not installed on your computer, please install it first
 echo by downloading it from http://www.python.org.  Alternately,
 echo specify the Python interpreter you wish to use via the PYTHON
 echo environment variable.
 echo.
 goto usage